1С-Предприятие 8.0. Практическое пособие разработчика

       

Отчет Рейтинг услуг


Отчет "Рейтинг услуг" будет содержать информацию о том, выполнение каких услуг принесло OOO "На все руки мастер" наибольшую прибыль в указанном периоде. На примере отчета "Рейтинг услуг" мы проиллюстрируем, как отбирать данные в некотором периоде, как задавать параметры запроса и как использовать в запросе данные из нескольких таблиц и включать в результат запроса все данные одного из источников.

Создадим новый объект конфигурации Отчет "РейтингУслуг". Перейдем на закладку "Макеты" и вызовем конструктор выходной формы.

Выберем объектную (ссылочную) таблицу справочника "Номенклатура" и виртуальную таблицу регистра накопления "Продажи.Обороты". Для того чтобы исключить неоднозначность имен в запросе, переименуем таблицу "Номенклатура" в "СпрНоменклатура" (контекстное меню правой кнопки мыши).

Затем установим курсор на таблицу "ПродажиОбороты" и вызовем диалог ввода параметров виртуальной таблицы:

Откроем диалог ввода параметров виртуальной таблицы


[173]

Укажем, что начало и конец периода будут переданы в соответствующих параметрах "ДатаНачала" и "ДатаОкончания" (символ "&" перед именем указывает, что это параметр запроса):

Затем выберем из таблиц поля "СпрНоменклатура.Ссылка" и "ПродажиОбороты.ВыручкаОборот":

Перейдем на закладку "Связи" и увидим, что конструктор уже создал связь между двумя выбранными таблицами – значение изменения регистра "Номенклатура" должно быть равно ссылке на элемент справочника "Номенклатура". [174]

Единственное, что нам останется сделать, это сбросить флаг "Все" у таблицы регистра и установить его у таблицы справочника.



Будем выбирать все элементы из справочника "Номенклатура"

Установка флага "Все" у таблицы справочника будет означать, что из справочника будут выбраны все элементы и этим элементам будет поставлено в соответствие значение оборота выручки из регистра. Таким образом, в результате запроса будут присутствовать все услуги, и для некоторых из них будут указаны обороты выручки. Для тех услуг, которые не оказывались в выбранном периоде, не будет указано ничего.




Перейдем на закладку "Условия" и зададим условия выбора элементов из справочника "Номенклатура". При задании условий выбора мы снова будем использовать параметры запроса. Первым условием должно быть то, что выбранный элемент не является группой (для этого следует переключиться в режим "Произвольное условие").

Вторым условием должно быть то, что выбранный элемент является услугой (это – "Простое условие"):



[175]

В дальнейшем, перед выполнением запроса, мы передадим в параметр "ВидНоменклатуры" – соответствующее значение перечисления.

Перейдем на закладку "Объединения/Псевдонимы" и укажем, что представление элемента справочника будет иметь псевдоним "Услуга", а поле регистра будет иметь псевдоним "Выручка":



Перейдем на закладку "Порядок" и укажем, что результат запроса должен быть отсортирован по убыванию значения поля "Выручка".

На закладке "Итоги" определим, что нужно выводить общие итоги, и они должны представлять собой сумму значений поля "Выручка":



На закладке "Отчет" сбросим флаг "Использовать построитель отчета".

Теперь перейдем на закладку "Выходная форма". Укажем, что параметры "ДатаОкончания" и "ДатаНачала" будут редактироваться в форме в полях ввода с типом "Дата". Для параметра "ВидНоменклатуры" мы наоборот снимем признак редактирования в форме:



Нажмем "ОК". Платформа сформирует макет и форму отчета Откроем модуль формы и найдем в нем процедуру "РейтингУслуг". [176]

В этой процедуре, в той части, где выполняется установка параметров запроса, определим значение параметра "ВидНоменклатуры" (исправления выделены жирным шрифтом):

   "ВЫБРАТЬ

   |    СпрНоменклатура.Ссылка КАК Услуга,

   |    СпрНоменклатура.Представление,

   |    ПродажиОбороты.ВыручкаОборот КАК Выручка



   |ИЗ

   |    Справочник.Номенклатура КАК СпрНоменклатура

   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ДатаНачала, &ДатаОкончания, , ) КАК ПродажиОбороты

   |        ПО ПродажиОбороты.Номенклатура = СпрНоменклатура.Ссылка

   |ГДЕ

   |    СпрНоменклатура.ЭтоГруппа = ЛОЖЬ

   |    И СпрНоменклатура.ВидНоменклатуры = &ВидНоменклатуры

   |

   |УПОРЯДОЧИТЬ ПО

   |    Выручка УБЫВ

   |ИТОГИ

   |    СУММА(Выручка)

   |ПО

   |    ОБЩИЕ";

   Запрос.УстановитьПараметр("ВидНоменклатуры", Перечисления.ВидыНоменклатуры.Услуга);

   Запрос.УстановитьПараметр("ДатаНачала", ДатаНачала);

   Запрос.УстановитьПараметр("ДатаОкончания", ДатаОкончания);

Теперь рассмотрим текст запроса, сформированный конструктором:

   Запрос.Текст =

   "ВЫБРАТЬ

   |    СпрНоменклатура.Ссылка КАК Услуга,

   |    СпрНоменклатура.Представление,

   |    ПродажиОбороты.ВыручкаОборот КАК Выручка

   |ИЗ

   |    Справочник.Номенклатура КАК СпрНоменклатура

   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ДатаНачала, [177] &ДатаОкончания, , ) КАК ПродажиОбороты

   |        ПО ПродажиОбороты.Номенклатура = СпрНоменклатура.Ссылка

   |ГДЕ

   |    СпрНоменклатура.ЭтоГруппа = ЛОЖЬ

   |    И СпрНоменклатура.ВидНоменклатуры = &ВидНоменклатуры

   |

   |УПОРЯДОЧИТЬ ПО



   |    Выручка УБЫВ

   |ИТОГИ

   |    СУММА(Выручка)

   |ПО

   |    ОБЩИЕ";

Сначала, как обычно, идет часть описания запроса и в ней есть новые для нас конструкции.

При описании источников запроса (после ключевого слова ИЗ), использована возможность определения нескольких источников запроса:

   |ИЗ

   |    Справочник.Номенклатура КАК СпрНоменклатура

   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ДатаНачала, &ДатаОкончания, , ) КАК ПродажиОбороты

   |        ПО ПродажиОбороты.Номенклатура = СпрНоменклатура.Ссылка

В данном случае выбираются записи из двух источников: "СпрНоменклатура" и "ПродажиОбороты", причем ключевым предложением ЛЕВОЕ СОЕДИНЕНИЕ... ПО описан способ, которым будут скомбинированы между собой записи этих двух источников.

ЛЕВОЕ СОЕДИНЕНИЕ означает, что в результат запроса надо включить комбинации записей из обоих источников, которые соответствуют указанному после ключевого слова ПО условию. Кроме этого, в результат запроса надо включить еще и записи из первого (указанного слева от слова СОЕДИНЕНИЕ) источника, для которых не найдено соответствующих условию записей из второго источника. [178]

В описании первого источника и условия соединения нет для нас ничего нового, а вот при описании второго источника, используется возможность задания параметров виртуальной таблицы запроса:

   |    РегистрНакопления.Продажи.Обороты(&ДатаНачала, &ДатаОкончания, , )

Первым параметром передается начало периода расчета итогов, вторым – конец периода. В результате исходная таблица будет содержать только обороты, рассчитанные в переданном периоде. Здесь всегда следует помнить, что если мы передаем в качестве этих параметров дату (а в нашем случае так и будет), то дата содержит и время с точностью до секунды.



Если заранее известно, что пользователя не будут интересовать результаты работы отчета в периодах, указанных с точностью до секунд, то следует учесть следующую особенность: по умолчанию время в дате установлено в 00:00:00. Поэтому, если не предпринять специальных мер, получится, что когда пользователь задаст период отчета с 01.03.2004 по 31.03.2004, итоги регистра будут рассчитаны с начала дня 01.03.2004 00:00:00 по начало дня 31.03.2004 00:00:00. Таким образом, данные за 31 число, отличные от начала дня, в расчет не войдут, что сильно удивит пользователя.

Для того чтобы исключить эту ситуацию, следует сделать две вещи.

Во-первых, в форме отчета ограничить пользователя в возможностях ввода даты начала и даты окончания, установив для соответствующих полей ввода состав даты как "Дата":

Определим состав даты...



[179]

Во-вторых, при передаче параметров использовать встроенную функцию КонецДня(). Для этого вернемся в модуль формы отчета и внесем необходимые изменения (добавления выделены жирным шрифтом):

Процедура ДействияФормыРейтингУслугСформировать(Кнопка)

   //{{КОНСТРУКТОР_ВЫХОДНЫХ_ФОРМ_ПРОЦЕДУРА_ВЫЗОВА(РейтингУслуг)

   // Данный фрагмент построен конструктором.

   // При повторном использовании конструктора, внесенные вручную изменения будут утеряны!!!

   ТабДок = ЭлементыФормы.ПолеТабличногоДокумента;

   РейтингУслуг(ТабДок, Неопределено, ДатаНачала, КонецДня(ДатаОкончания));

   //}}КОНСТРУКТОР_ВЫХОДНЫХ_ФОРМ_ПРОЦЕДУРА_ВЫЗОВА

КонецПроцедуры

Продолжим рассматривать текст запроса. В части описания запроса есть еще одна новая для нас конструкция – задание условий отбора данных из исходных таблиц:

   "ВЫБРАТЬ

   |    СпрНоменклатура.Ссылка КАК Услуга,

   |    СпрНоменклатура.Представление,

   |    ПродажиОбороты.ВыручкаОборот КАК Выручка

   |ИЗ



   |    Справочник.Номенклатура КАК СпрНоменклатура

   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ДатаНачала, &ДатаОкончания, , ) КАК ПродажиОбороты

   |        ПО ПродажиОбороты.Номенклатура = СпрНоменклатура.Ссылка

   |ГДЕ

   |    СпрНоменклатура.ЭтоГруппа = ЛОЖЬ

   |    И СпрНоменклатура.ВидНоменклатуры = &ВидНоменклатуры

Условию отбора всегда предшествует ключевое слово ГДЕ. После него описывается само условие. Обратите внимание, что поля исходных таблиц, на которые накладывается условие, могут и не входить в список выборки (как в нашем случае). Кроме того, в нашем условии использован параметр запроса "ВидНоменклатуры". [180]

Далее в запросе следует часть упорядочивания результатов, а за ней – новая для нас часть, которая не встречалась ранее – описание итогов:

   |ИТОГИ

   |    СУММА(Выручка)

   |ПО

   |    ОБЩИЕ";

Она всегда начинается с ключевого слова ИТОГИ, за которым следует описание того, какие итоги будут присутствовать в результате запроса. Сразу после слова ИТОГИ описываются агрегатные функции, которые необходимо рассчитывать в итогах. В нашем случае будет рассчитываться сумма по полю "Выручка". Затем следует ключевое слово ПО, после которого описываются группировки, в которых должны быть рассчитаны итоги. В нашем случае они отсутствуют, и используется только ключевое слово ОБЩИЕ, которое указывает на то, что итоги будут рассчитаны по всей таблице в целом.

Теперь, когда мы закончили знакомиться с текстом запроса, запустим 1С:Предприятие в режиме отладки и посмотрим, как работает наш отчет.

Зададим период отчета с 01.03.2004 по 30.04.2004. Результат будет выглядеть следующим образом:



[181]

Теперь изменим дату окончания на 31.03.2004 и убедимся, что данные за 31 марта попадают в отчет:



Таким образом, на примере этого отчета мы продемонстрировали, как отбирать данные в некотором периоде, как задавать параметры запроса и как использовать в запросе данные из нескольких таблиц и включать в результат запроса все данные одного из источников. [182]


Содержание раздела